Ｒ Ｐ Ｇ 演 算 仕 様 書
前ページ 次ページ 目 次

演算仕様書は、ＣＯＢＯＬのＰＲＯＣＥＤＵＲＥ ＤＩＶＩＳＩＯＮに相当します。


まずは、サンプル・プログラムをごらん下さい。以下のサンプル・プログラムで見て
行くこととします。

このプログラムは得意先マスター（Ｍ４２０）をよみ、内容を印刷します。
このとき、売上は１０００で割った値つまり、千円単位で表示します。余りは、切り
捨てです。

入力

入力ファイル（Ｍ４２０）は次のように定義してあるものとします。

得意先マスター（レコード様式 ： Ｍ４２０Ｒ）
フィールド名 長さ タイプ  小数点以下 見出し名
TKDEL １ Ａ    削除フラグ
TKTKNO ５ Ａ   得意先№
TKNMKJ ４２ Ｏ   得意先名
TKNMKN ２０ Ａ   得意先カナ
TKTEL １２ Ａ   電話番号
TKＳＬＮＯ ４ Ａ   営業担当
TKFLG １ Ａ   フラグ
TKUR\ １１ Ｓ ０ 売上実績


出力
出力は印刷ファイル（ＬＭ４２０ＡＰ）として、次のように印刷するように定義して
あるものとします。
XXXXX XXXXXXXXXXXXXXXX..XXXX XXXXXXXXXXXXXXXXXXXX XXXXXXXXXXXX 99999999
XXXXX XXXXXXXXXXXXXXXX..XXXX XXXXXXXXXXXXXXXXXXXX XXXXXXXXXXXX 99999999
XXXXX XXXXXXXXXXXXXXXX..XXXX XXXXXXXXXXXXXXXXXXXX XXXXXXXXXXXX 99999999


フィールド名 長さ タイプ 小数点以下 カラム 見出し名
P@TKNO ５ Ａ    ３ 得意先№
P@NMKJ ４２ Ｏ   １０ 得意先名
P@NMKN ２０ Ａ   ５４ 得意先カナ
P@TEL １２ Ａ   ７６ 電話番号
P@UR\ ８ Ｓ ０ ９１ 売上実績

サンプル・プログラム 
     H*===============================================================
     H* ID   : LM420
     H* NAME : 得意先一覧表印刷
     H* FUNC : 得意先マスターファイルについて、キー順に順次よみ、
     H*        同一覧表を印刷する。
     H*
     H*===============================================================
     H            Y/                                    1
     F*===============================================================
     FM420    IF  E           K        DISK
     F*
     FLM420AP O   E                    PRINTER
     C*===============================================================
     C* 1.前処理
     C                     READ M420R                    99
     C* 2.本処理
+----C           *IN99     DOWEQ*OFF
|    C*
|    C                     MOVELTKTKNO    P@TKNO            得意先№  
|    C                     MOVELTKNMKJ    P@NMKJ            得意先名  
|    C                     MOVELTKNMKN    P@NMKN            得意先カナ
|    C                     MOVELTKTEL     P@TEL             電話番号  
|    C           TKUR\     DIV  1000      P@UR\             売上実績  
|    C*                                                     
|    C                     WRITEDTL01                       
|    C*                                                     
|    C                     READ M420R                    99 
+----C                     ENDDO                            
     C* 3.後処理
     C                     SETON                     LR
     C                     RETRN


演算仕様書の様式
１～５桁 パンチカード時代のなごりの順序番号用のフィールドです。
６桁 演算仕様書の仕様書コードＣを指定します。
７桁 その行すべてを注釈とするとき’＊’を記述します。
９～17桁 実行制御用の標識を指定します。
18～23桁 演算用の因子１を指定します。
28～32桁 演算のコマンドを指定します。
33～42桁 演算用の因子２を指定します。
43～48桁 演算結果を指定します。
49～51桁 変数を定義する場合、その桁数を指定します。
52桁 数値変数を定義する場合、その小数点以下の桁数を指定します。
54～59桁 演算結果、標識セットがある場合指定します。


説明１： 
     C*===============================================================
     C* 1.前処理
     C                     READ M420R                    99
１、２行目：プログラムを読みやすくするためのコメントです。
３行目 ： 読み取りをおこなっています。
ＲＥＡＤ ：順次読み取りです。
Ｍ４２０Ｒ： ファイルＭ４２０のレコード様式Ｍ４２０Ｒを読取りしています。
９９ ：ＥＯＦのとき、９９番の標識がＯＮになります。
          よみとりＯＫのときはＯＦＦです。
           ＯＮ／ＯＦＦは具体的には’１’／’０’です。標識は０１～９９が使えます。
ＣＯＢＯＬでは、概略次のようなコーディングに相当します。

             READ     M420    AT    END    MOVE    '1'    TO    標識９９.

            （一般のＣＯＢＯＬには標識９９はありません。）

参考 ： ＡＳ／４００のＣＯＢＯＬでは、インディケータとして、 
      07  SWITCHES  PIC 1
                    OCCURS  99  TIMES
                    INDICATORS 01.
のように定義されます。ＳＷＩＴＣＨＥＳ（１）～ＳＷＩＴＣＨＥＳ（９９）


説明２： 
...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* 2.本処理
+----C           *IN99     DOWEQ*OFF
|
|         ･･･
|
+----C                     ENDDO
ＤＯＷＥＱ ：   ＤＯ－ＷＨＩＬＥ－ＥＱです。ＰＥＲＦＯＲＭに相当します。
＊ＩＮ９９ ：     標識９９番の意味です。値は＊ＯＮか＊ＯＦＦのどちらかです。
ＥＮＤＤＯ ：    ＥＮＤ－ＤＯで、ＥＮＤ－ＰＥＲＦＯＲＭに相当します。
＋－－－－：範囲をわかりやすくするために、1～５桁を使用しています。


説明３： 
...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C                     MOVELTKTKNO    P@TKNO             得意先№  
     C                     MOVELTKNMKJ    P@NMKJ             得意先名  
     C                     MOVELTKNMKN    P@NMKN             得意先カナ
     C                     MOVELTKTEL     P@TEL              電話番号  
     C           TKUR\     DIV  1000      P@UR\              売上実績
ＭＯＶＥＬ： ＭＯＶＥ－ＬＥＦＴで左詰め格納です。
ＤＩＶ ：   ＤＥＶＩＤＥ（除算）でＴＫＵＲ￥／１０００をＰ＠ＵＲ￥に格納します。
               このとき、小数以下は切り捨てられます。


説明４： 
     C* 3.後処理
     C                     SETON                     LR
     C                     RETRN
ＳＥＴＯＮ ： 標識をＯＮにします。ここではＬＲ標識をＯＮにしています。
ＬＲ標識 ： ＬＡＳＴ－ＲＥＣＯＲＤ標識です。これがＯＮになるとＲＰＧプログラムは終了します。
ＲＥＴＲＮ ：ＲＥＴＵＲＮで呼び出し側へ制御を返します。


標識

ＡＳ／４００ソフトウエアの体系では、標識を多用しています。
ＲＰＧで使用できる標識は次のようなものがあります。
（ただし、ここでは全てを説明するわけではありません。）
01-99 一般標識 プログラムの中でプログラマーが自由にオン・オフできる
KA-KN、KP-KY 機能キー標識 Ｆキーに対応する。Ｆ１～Ｆ１２、Ｆ１３～Ｆ２４
L1-L9 制御レベル標識 キーブレーク処理用
LR 最終レコード標識 最終レコードを読取したときオン。ファイルはクロースされる。
MR 突合せレコード標識  
H1-H9 停止標識 ほぼ、ＳＴＯＰ リテラルに相当
ＲＴ 戻り標識  
Ｕ１－Ｕ８ 外部標識  いわゆるＵＰＳＩです。
OA-OG,OV オーバーフロー標識  


ＲＰＧサイクル

ＲＰＧは実行時、ＲＰＧサイクルと呼ばれる手順で処理をしています。
疑似コーディングで表わすと次のようになります。 
ＤＯ ＵＮＴＩＬ（ＬＲがＯＮになるまで）
      
      １．見出しおよび明細の出力
      ２．入力レコードの入手
      ３．合計演算の実行（Ｌ１～Ｌ９，ＬＲ標識による）Ｃ仕様書の部分
      ４．合計出力の書き出し
      ５．ＩＦ ＬＲ＝オフ ＴＨＥＮ
          ５．１ 入力からフィールドの転送
          ５．２ 明細演算の実行 （Ｃ仕様書の部分）
      ＥＬＳＥ
          ５．３終了処理
      ＥＮＤＩＦ
      
ＥＮＤ－ＤＯ
このＲＰＧサイクルに沿ったプログラムを記述すれば、上記でＣ仕様書の部分だけのコーディングになり、
簡潔なプログラムが作れるのですが、ＣＯＢＯＬプログラマーにはあまりなじみがないので、ここでは
取り上げません。
上記処理サイクル中の５．２の明細演算の実行の部分だけで、さらに繰返し処理を実現する方法で、
話をすすめます。（サイクルプログラムは、ＲＰＧプログラマーでも尻込みをする人が多い）


ＲＰＧの命令

ＲＰＧの命令は約１００種あります。（ＡＰＰＥＮＤＥＸを参照）
概略をサンプルで示します｡

演算命令
加減乗除
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* 加減乗除
     C*          要素１    命令 要素２    結果              意味 
     C                     Z-ADD123       A                A=0+123    
     C                     Z-SUB456       B                B=0-456    
     C           A         ADD  B         C                C=A+B      
     C           D         SUB  E         F                F=D-E      
     C           G         MULT H         I                I=G*H      
     C           J         DIV  K         L                L=J/K 
     C                     MVR            AMARI             余り取得
     C*
     C* 四捨五入： ５３桁目をＨとすると、小数以下第１位を四捨五入して割付。
     C           M         DIV  N         P         H       四捨五入


割付・連結命令
         C* １．割付                                                         
         C                     MOVELQQ        RR                左詰割付 
         C                     MOVE SS        TT                右詰割付 
         C                     MOVEL*BLANK    UU                SPACE    
         C                     MOVEL*ZERO     VV                ZERO

         C* ２．残りクリア： ５３桁目をＰとする、残りはブランクになる
         C                     MOVEL'***'     WW        P       残りをブランク
     
         C* ３．連結                                                          
         C           UU        CAT  VV        WW               WW=UU || VV
補足説明
１．ＭＯＶＥＬ，ＭＯＶＥとも割りつけ元が短いとき、割付先の残りはそのままになります。
      例：ＲＲが１０バイトで’ＡＢＣＤＥＦＧＨＩＪ’、ＱＱが’ＸＹＺ’のとき、
             ＭＯＶＥＬ ’ＸＹＺ’           ＲＲ
             なら、ＲＲは’ＸＹＺＤＥＦＧＨＩＪ’に、
             ＭＯＶＥ    ’ＸＹＺ’           ＲＲ
             なら、ＲＲは’ＡＢＣＤＥＦＧＸＹＺ’になります。

２．残りをブランクにするためには、５３桁目をＰとします。
     ＊ＢＬＡＮＫ，＊ＺＥＲＯのときは長さは割り付け先にあわされます。


文字列処理
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* 文字列の連結
     C                     MOVEL'AA'      AAA  2
     C                     MOVEL'BBB'     BBB  3
     C           AAA       CAT  BBB       CCC  5
     C* 文字列の切り出し
     C                     MOVEL'ABCDEFGH'DDD  8
     C                     Z-ADD5         LEN  30
     C                     Z-ADD2         T    20
     C           LEN       SUBSTDDD:T     EEE  5
     C*

補足説明
１．文字列の連結
上の例で、ＣＣＣは’ＡＡＢＢＢ’になります。ＰＬ／ＩのＣＣＣ＝ＡＡＡ ｜｜ ＢＢＢ；に相当します。

２．文字列の切り出し
上の例で、ＥＥＥは、’ＢＣＤＥＦ’になります。


プログラム実行制御命令

処理の条件分岐 ： ＩＦ ～ ＴＨＥＮ ～ ＥＬＳＥ 
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* ＩＦ ～ ＴＨＥＮ ～ ＥＬＳＥ
     C           AA        IFEQ 12
     C                     MOVEL'AAA'     CC
     C                     ELSE
     C                     MOVEL'BBB'     CC
     C                     ENDIF
     C* ＡＡ＝１２ならＣＣは’ＡＡＡ’にそうでないとき’ＢＢＢ’になる。
     C*
     C*  各種ＩＦ                                            意味
     C          AA        IFEQ BB                          AA ＝ BB
     C          AA        IFNE BB                          AA ≠ BB
     C          AA        IFGT BB                          AA ＞ BB
     C          AA        IFGE BB                          AA ≧ BB
     C          AA        IFLT BB                          AA ＜ BB
     C          AA        IFLE BB                          AA ≦ BB
     C*
 
補足説明
一般形：ＩＦｘｘの形、ｘｘはＥＱ，ＮＥ，ＧＴ，ＧＥ，ＬＴ，ＬＥ
       条件の組合せ：ＡＮＤｘｘ，ＯＲｘｘ
       ＩＦにつづけて、ＡＮＤｘｘ，ＯＲｘｘをコーディングする。


例 ：ＩＦにおける条件の組み合せ
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C           AA        IFGE 11
     C           AA        ANDLE50 
     C                     MOVEL'AAA'     CC
     C                     ELSE
     C                     MOVEL'BBB'     CC
     C                     ENDIF
補足：ＡＡが１１～５０のとき、CCは’ＡＡＡ’になる、そうでないときは’ＢＢＢ’になる


繰り返し処理 ： ＤＯ
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* １ .ＤＯＷｘｘ ～ ＥＮＤＤＯ
     C*    Ａ＝Ｂの間、繰り返し実行
     C           A         DOWEQB
     C*                      処理１
     C*                      処理２
     C*                      ・・・
     C                     ENDDO
     C*
     C* 2.Ｘを１からＮまで変化させながら、Ｎ回繰り返し実行
     C           1         DO    N         X
     C*                      処理１
     C*                      処理２
     C*                      ・・・
     C                     ENDDO
     C* 3.ＤＯループの脱出（ＬＥＡＶＥ命令で脱出する。）
     C           A         DOWEQB
     C*                      処理１
     C*                      処理２
     C           CC        IFGT DD
     C                     LEAVE
     C                     ENDIF
     C                     ENDDO
 
補足：１．繰り返し条件が複合するの場合は、ＩＦの場合と同じく、
          ＡＮＤｘｘ，ＯＲｘｘをつづける。
      ２．ＣＯＢＯＬの次の例に相当する。
          PERFORM    VARYING  X  FROM  1  BY  1  UNTIL  X=N
                     処理１
                     処理２
                     ・・・
          END-PERFORM.
      ３．ＬＥＡＶＥ命令を実行すると、繰り返し処理をやめ、ＥＮＤＤＯの後ろに
          制御が移る。


内部サブルーチンの呼出 
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* 3.サブルーチン呼出
     C                     EXSR           SBAAA
          ・・・
          ・・・
     C*呼び出されるサブルーチン
     C           SBAAA     BEGSR
     C*
     C*                    処理１
     C*                    処理２
     C*                   ・・・
     C                     ENDSR
補足 ： ＣＯＢＯＬのＰＥＲＦＯＲＭに相当。


ケース処理によるサブルーチンの呼出 
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* ＣＡＳＥ処理によりサブルーチン呼出。
     C*    ＢＢが１０ならＳＢＰＰ、２０ならＳＢＱＱ、３０ならＳＢＲＲを呼出す
     C           BB        CASEQ10        SBPPP
     C           BB        CASEQ20        SBQQQ
     C           BB        CASEQ20        SBRRR
     C                     ENDCS
補足：ＣＡＳｘｘは演算項目１と項目２の比較条件成立のとき、サブルーチンを呼出す。
           一般形はＣＡＳｘｘ。ｘｘは条件でＩＦの場合に同じ。条件複合の場合も同様。


ケースによる分岐処理 ： ＳＥＬＥＣＴ ～ ＷＨＥＮ
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* ＳＥＬＣＴ～ＷＨＥＮ
     C                     SELEC
     C           CC        WHEQ 'A'
     C                     Z-ADD100       XXX
     C           CC        WHEQ 'B'
     C                     Z-ADD200       XXX
     C           CC        WHEQ 'C'
     C                     Z-ADD300       XXX
     C                     OTHER
     C                     Z-ADD999       XXX
     C                     ENDS
補足：ＸＸＸはＣＣがＡなら１００、Ｂなら２００、Ｃなら３００、その他なら９９９になります。


入出力命令 
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* １．データベース入出力
     C*     順読みと逆順よみ
     C                     READ AAAR                       順読み
     C                     READPAAAR                       逆順読み
補足：逆順読みをするときは、予め、読取位置を目的の位置へのセットする操作が必要。


読取位置の位置づけ ： ＳＥＴＬＬ ， ＳＥＴＧＴ
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* 位置づけ
     C* １．キーの値を超えない位置に位置づけ( SET LESS THAN )
     C           KEY11     SETLLBBBR                       
     C* ２．キーの値よりも大きい位置に位置づけ( SET GREATER THAN )
     C           KEY12     SETGTBBBR                       
     C*

補足：ＢＢＢＲはレコード様式名とします。
      次のようなデータがあるとして、ＫＥＹ１１が１５とすると、
      上の例のＳＥＴＬＬ命令を実行すると、キー１０と２０の間に位置づけられます。
      上の例でＫＥＹ１２が５０とすると、キー３０の後ろに位置づけられます。
      ＣＯＢＯＬのＳＴＡＲＴ命令に相当します。
キ ー デ ー タ
１ ０ ＤＡＴＡ －１
２ ０ ＤＡＴＡ －２
３ ０ ＤＡＴＡ －３


キーによる位置づけと読みとりの組み合せ（正順よみと逆順よみ） 
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C*１． 正順読み（ＫＥＹ１１の次から）
     C           KEY11     SETLLBBBR                       位置づけ
     C                     READ BBBR                     99
     C           *IN99     DOWEQ*OFF
     C*                    処理１
     C*                    処理２
     C*                   ・・・
     C                     READ BBBR                     99
     C                     ENDDO
     C*
     C*２． 逆順読み（一番最後から）
     C           *HIVAL    SETGTBBBR                        最後へ位置付け
     C                     READPBBBR                     99 逆読み
     C           *IN99     DOWEQ*OFF
     C*                    処理Ａ
     C*                    処理Ｂ
     C*                   ・・・
     C                     READPBBBR                     99 逆読み
     C                     ENDDO
補足説明 ：
１．プログラム開始時は先頭レコードに位置づけされています。
２．逆読みするときは、最終レコードのさらに後ろに位置づけする。このため、＊ＨＩＶＡＬを使います。


同一キーのレコードを読む
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* １．データベース入出力
     C* １．正順、同一キー：ＫＥＹ１１と同じものを持つレコードをよむ。
     C           KEY11     READEBBBR                     98
     C*
     C* ２．逆順、同一キー：ＫＥＹ２２と同じものを持つレコードをよむ。
     C           KEY11     REDPEBBBR                     98
補足：
１．の例で、ＫＥＹ１１を２０とすると、下のＤＡＴＡ－２からＤＡＴＡ－４が読取されます。
ＤＡＴＡ－５をよみとりしようとすると標識９８がオンになります。

データ
キー１ データ キー２
１０ ＤＡＴＡ － １ Ａ
２０ ＤＡＴＡ － ２ Ａ
２０ ＤＡＴＡ － ３ Ｂ
２０ ＤＡＴＡ － ４ Ｃ
３０ ＤＡＴＡ － ５ Ａ


特定のキーをもつレコードの単独よみ 
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* レコードの単独よみ
     C*     （ＫＥＹ２２で与えられた値のキーを持つレコードをよむ）
     C           KEY22     CHAINCCCR
     C*
補足：一連のＲＥＡＤと異なり、ＣＨＡＩＮでは読取位置は移りません。何度でも同じレコードが読まれます。


レコードの追加、置換え、削除
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* １．追加
     C                     WRITEDDDR
     C* ２．置換え
     C                     UPDATDDDR
     C* ３．削除
     C                     DELETDDDR
補足 ：
１．ＷＲＩＴＥはレコードの件数が増加します。Ｆ仕様書でレコード件数増加の定義が必要です。
２．ＵＰＤＡＴは、一度ＲＥＡＤやＣＨＡＩＮ命令で一度読み込みしたものを置き換えします。
   （読取していないレコードを置き換え処理できません）
３．ＤＥＬＥＴは、一度ＲＥＡＤやＣＨＡＩＮ命令で一度読み込みしたものを削除します。
  （読取していないレコードを削除処理できません）


定義命令

キーリスト

レコードのキーは１つのフィールドだけとは限りません。
また、１ヶ所にかたまってまっているとも限りません。（       ）内はフィールド名とします。
キー１
（ＫＦＬＤ１）		 データ１ キー２
（ＫＦＬＤ２）		 キー３
（ＫＦＬＤ３）		 データ２
１０ ＤＡＴＡ１ Ａ ２００ ＤＡＴＡ－Ａ
２０ ＤＡＴＡ２ Ｂ ２００ ＤＡＴＡ－Ｂ
３０ ＤＡＴＡ３ Ｂ ４００ ＤＡＴＡ－Ｃ
このような、複数の散在したキーを扱うためには、キーリストと呼ぶキーの定義を行って、
それによって、ＳＥＴＬＬや、ＲＥＡＤＥ、ＣＨＡＩＮなどに指定します。
（もちろん、１個のキー項目で、１つのキーリストにすることもできます。）

キーリストのコーディング
キーの順は、キー１、２、３の順に定義されているものとして、上記の例のコーディングは次のようになります。
 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* キーリスト
     C           KEY11     KLIST
     C                     KFLD           KFLD1
     C                     KFLD           KFLD2
     C                     KFLD           KFLD3

画面入出力

ワークステーションの画面との入出力をするにはＤＳＰＬＹを使用します。

 ...+....1....+....2....+....3....+....4....+....5....+....6....+....7..
     C* 画面への表示のみ
     C           MSG1      DSPLY
     C* 画面への表示と応答の取得
     C           MSG2      DSPLY          REPLY

結果のフィールドに変数を指定すると、画面からの応答を受取ることができます。



前ページ 次ページ 目 次

（Ｃ）ＣＯＰＹＲＩＧＨＴ ＩＳＨＩＯＫＡ ＫＡＴＳＵＨＩＤＥ ２０００－２００３