Ｒ Ｐ Ｇ 入 力 仕 様 書
前ページ 次ページ 目次


入力仕様書では、ファイルのレコードの構造を記述します。
ＣＯＢＯＬのＦＤとＷＯＲＫＩＮＧ−ＳＴＯＲＡＧＥ ＳＥＣＴＩＯＮでの、ＰＩＣＴＵＲＥ定義に相当します。



ＡＳ／４００のＲＰＧでは、Ｆ仕様書で述べたように、外部記述を利用しているときは、
その様式をプログラム内部で改めて定義し直すようなことはほとんどありません。

Ｉ 仕様書は、例外的にファイルのフィールド（ＣＯＢＯＬのデータ項目）を再定義するよ
うな場合と、プログラムの中で使用する構造をもったワーク・フィールドを定義するような
場合に使用します。

Ｉ 仕様書では様式は２種類あります。

様式１ ： データ構造指示の始まりをしめす様式です。
７〜１１桁 データ構造名を指示します。構造名は省略できます。
データ構造名は英字で始まる６桁までの英数字の文字列です。
１９、２０桁 ’ＤＳ’と指示します。

様式２ ： フィールド（データ項目）をしめす様式です。
４３桁 フィールドのデータタイプを指示します。
Ｐはパック１０進数です。
ブランクは文字列もしくはゾーン１０進数です。
４４〜４７桁 フィールドの始まりの桁を指示します。
４８〜５１桁 フィールドの終りの桁を指示します。
５２桁 フィールドの小数点以下の桁を指示します。
ブランクにするとフィールドは文字列です。
５３〜５８桁 フィールドの名前は英字で始まる６桁までの英数字の文字列です。


例−１： 
 ...+... 1 ...+... 2 ...+... 3 ...+... 4 ...+... 5 ...+... 6 ...+
     I            DS
     I                                        1   80W@YMD
     I                                        1   40W@YYYY
     I                                        5   60W@MM
     I                                        7   80W@DD
この例で、Ｗ＠ＹＭＤに１９９９１２２３をセットすると、それぞれ次のように
なります。
Ｗ＠ＹＹＹＹ １９９９
Ｗ＠ＭＭ １２
Ｗ＠ＤＤ ２３

ＣＯＢＯＬでは上の例は次のようになります。Ｗ＠ＹＭＤとＷ＠ＹＹＹＹが一部
同じ場所（アドレス）を占めていることに注意してください。
（説明のためのもので、＠がＣＯＢＯＬで使用できるという意味ではありません）
       01  DUMMY.
           02  W@YMD                    PIC  S99999999.
           02  W@YYYY  REDEFINS  W@YMD  PIC  S9999.
           02  W@MM                     PIC  S99.
           02  W@DD                     PIC  S99.

例−２： 
 ...+... 1 ...+... 2 ...+... 3 ...+... 4 ...+... 5 ...+... 6 ...+
     IW\YMD       DS
     I                                        1   80W@YMD
     I                                        1   40W@YYYY
     I                                        5   60W@MM
     I                                        7   80W@DD
Ｗ￥ＹＭＤとＷ＠ＹＭＤの違い
Ｗ￥ＹＭＤは文字列、Ｗ＠ＹＭＤはゾーン１０進数です。

例−３：漢字シフトコードの定義。
ＡＳ／４００では漢字を扱うとき、シフトアウト（Ｘ’０Ｅ’）、シフトイン（Ｘ’０Ｆ’）のシフトコードを
使用します。漢字文字列を強制的に分割するような場合に必要になることがあります。
この例では、漢字シフトコード、Ｘ’０Ｅ’，Ｘ’０Ｆ’を定義しています。
     I*. 1 ...+... 2 ...+... 3 ...+... 4 ...+... 5 ...+... 6 ...+... 7 
     I            DS                                                   
     I I            ' 漢字 '                  1   6 W@DUMY             
     I                                        1   1 X0E                
     I                                        6   6 X0F

例−４：１６進数による初期値
次のＡ１２３４とＢ１２３４は同じ値が入っています。 
     I*. 1 ...+... 2 ...+... 3 ...+... 4 ...+... 5 ...+... 6 ...+... 7 
     I* １．１６進数による初期値
     I            DS                                                   
     I I            X'F1F2F3F4'               1   4 A1234             
     I* ２．文字列による初期値             
     I            DS
     I I            '1234'                    1   4 B1234


ローカルデータ域（＊ＬＤＡ）

ローカルデータ域はＲＰＧではＩ仕様書の中で’ＵＤＳ’として定義します。これはプログラム間でデータを
簡単に引き継ぐことのできるデータ構造です。

いま２本のプログラム、ＴＵＤＳ１、ＴＵＤＳ２の間でデータを受け渡す例を示します。
このプログラムは次のようにＴＵＤＳ１，ＴＵＤＳ２の順にＲＵＮします。介在するのはローカル・データ域だけです。
ローカル・データ域は自動的にプログラムにデータが取得され、ＬＲ標識をオンにして終了すると、出力されます。

プログラム　ＴＵＤＳ１
　　↓
　　＊ＬＤＡ　　　　　　
　　↓
プログラム　ＴＵＤＳ２


プログラム：ＴＵＤＳ１
     H            Y-                                                   
     F*--------------------------------------------------------------- 
     I           UDS                                                   
     I                                        1   2 FLD1               
     I                                        3  12 FLD2               
     C*--------------------------------------------------------------- 
     C           *ENTRY    PLIST                                       
     C                     PARM           P@FLD  12                    
     C*--------------------------------------------------------------- 
     C                     MOVELP@FLD     FLD1                         
     C                     MOVE P@FLD     FLD2                         
     C                     SETON                     LR                
     C                     RETRN


DSPDTAARA DTAARA(*LDA)
                                 データ域表示                                   
                                                          システム :   S1234567 
 データ域  . . . . . . . :   *LDA                                               
 タイプ  . . . . . . . . :   *CHAR                                              
 長さ  . . . . . . . . . :   1024                                               
 テキスト  . . . . . . . :    ジョブ 076515/ISHIOKA/QPADEV0004 用の *LDA        
                                                                                
                                                                                
            値                                                                  
 ｵﾌｾｯﾄ      *...+....1....+....2....+....3....+....4....+....5                  
     0     'ABCDEFGHIJKL                                      '                 
    50     '                                                  '                 
   100     '                                                  '                 
   150     '                                                  '                 
   200     '                                                  '                 
   250     '                                                  '                 
   300     '                                                  '                 
   350     '                                                  '                 
   400     '                                                  '                 
                                                                       続く ...


プログラム：ＴＵＤＳ２
     H            Y-                                                   
     F*--------------------------------------------------------------- 
     I           UDS                                                   
     I                                        1   2 FLD3               
     I                                        3  12 FLD4               
     C*--------------------------------------------------------------- 
     C           FLD3      DSPLY                                       
     C           FLD4      DSPLY                                       
     C                     SETON                     LR                
     C                     RETRN


実行結果は次のようになります。


5 > CALL TUDS1 'ABCDEFGHIJKL'
5 > CALL TUDS2
DSPLY AB
DSPLY CDEFGHIJKL


ユーザー・データ域

ユーザー・データ域（ＵＤＡ）もローカル・データ域に似たデータ・エリアです。
ローカル・データ域と同様、ＵＤＳとしてデータ構造を定義します。
違いはローカルデータ域が各ジョブに１個自動的に割り振られ、自動的に削除されるのに対し、
ユーザー・データ域はファイルのようにいくつでも生成でき、削除するまで存在するということです。
作成コマンドは、ＣＲＴＤＴＡＡＲＡです。

ユーザー・データ域のデータは、ＲＰＧでは演算仕様書のＩＮ命令で取得し、ＯＵＴ命令で出力します。



前ページ 次ページ 目次

（Ｃ）ＣＯＰＹＲＩＧＨＴ ＩＳＨＩＯＫＡ ＫＡＴＳＵＨＩＤＥ ２０００−２００３